/*==== DEFINES ==============================================================*/
EXCEPTION_STACK_SIZE   = 0x200; /*assigned for FIQ,IRQ,Abort,undef Mode in start.s*/
EXCEPTION_STACK_TOTAL  = 0x800; /*assigned for FIQ,IRQ,Abort,undef Mode in start.s*/

/*==== Linker options =======================================================*/
--default_order
-f 0
-c                      /* LINK USING C CONVENTIONS */
-stack  0x00001000      /* SOFTWARE STACK SIZE */
-heap   0x00080000      /* HEAP AREA SIZE */
-e _reset   /*c15*/


/*-----------------------------------------------------------------------------
| Memory map definition
+------------------------------------------------------------------------------
MEMORY
{
    DATA_INT      : org = 0x40200000    len = 0x00010000 /* INT SRAM */
    LOAD_MEM      : org = 0x80000000    len = 0x00080000 /* EXT DDR-RAM */
    HEAP_MEM      : org = 0x80080000    len = 0x00080000 /* EXT DDR-RAM */
}

/*-----------------------------------------------------------------------------
| Mapping of COFF sections into memory:
+------------------------------------------------------------------------------
| Defines the mapping between COFF sections and physical memory locations on
| the platform.
+----------------------------------------------------------------------------*/
SECTIONS
{
   /***************************************************************************
    * Code sections
    **************************************************************************/
    .boot        	 : palign(4) {} load = LOAD_MEM
    .intmem_bootcode     : palign(4) {} load = LOAD_MEM, run = DATA_INT, START(__BOOT_START), END(__BOOT_END), RUN_START(__BOOT_RUN)


    GROUP
    {
        .text         : palign(4) {}
    	.const        : palign(4) {}
	.consttbl     : palign(4) {} 
      	.pinit        : palign(4) {}
     } load = LOAD_MEM START(__CODE_START), END(__CODE_END), RUN_START(__CODE_RUN)

    .cinit        : palign(4) {} > LOAD_MEM

   /***************************************************************************
    * Initialized and uninitialized data sections (located in RAM)
    **************************************************************************/
    .intmemdata	 : {} > DATA_INT
    .bss         : {} > DATA_INT
    .sysmem      : {} > HEAP_MEM
    .stack       : {} > DATA_INT

    .ex_stack    : 
    {
        __EXCEPTION_STACK_START = .;

        _FIQstack_end = .;        . += 0x200;        _FIQstack_begin = .;
        _IRQstack_end = .;        . += 0x200;        _IRQstack_begin = .;
        _ABTstack_end = .;        . += 0x200;        _ABTstack_begin = .;
        _UNDstack_end = .;        . += 0x200;        _UNDstack_begin = .;

    }                 > DATA_INT

}

/*==== END OF FILE ==========================================================*/